Kwasowa Grota Heroes VIIMight & Magic XDark MessiahHorn of the AbyssHistoria Światów MMSkarbiecCzat
Cmentarz jest opustoszały
Witaj Nieznajomy!
zaloguj się    załóż konto
Niebiańska Kuźnia  (WoG, HotA, VCMI)temat: [WoG, ERA] Skrypty ERM
komnata: Niebiańska Kuźnia (WoG, HotA, VCMI)
strona: 1 - 2 - 3 ... 40 - 41 - 42 ... 81 - 82 - 83

Altair PW
21 maja 2008, 02:27
Najprostszy skrypt na to:


ZVSE

!?CM2;
!!CM:I?y2 F?y3;
!!HE-1:N?y4;
!!UN:J8/1/^%Y4.bmp^;
!!FU&-1:E;
!!VRz111:S^..\data\%Y4.bmp^;
!!HEy4:B3/?z7;

!!FU&y2<>45/y3<>0:E;
!!VRz5:S^^;
!!IF:D5/z5/z5/z6/z111/z5/z5/z5/z5/z5/z5/z5/z5/z5/z5/z5;
!!IF:F5/z5/z5/z5/z5/0;
!!IF:E1/5;


lub

ZVSE

!?CM2;
!!CM:I?y2 F?y3;
!!HE-1:N?y4;
!!UN:J8/1/^%Y4.bmp^;
!!FU&-1:E;
!!VRz111:S^..\data\%Y4.bmp^;
!!HEy4:B3/?z7;

!!FU&y2<>45/y3<>0:E;
!!VRz5:S^^;
!!IF:B1/z111/0;
!!IF:P1;

Skrypt w zależności od numeru bohatera dobiera sprawdza czy plik istnieje i w wypadku gdy funkcja zwróci true wyświetla obrazek. Oczywiście dopuszczalne formaty to bmp, gif i jpg.



Maiden PW
23 maja 2008, 10:22
Na wstępie chciałabym wszystkich pozdrowić. Od jakiegoś czasu śledzę, co się dzieje w tym temacie i bardzo się zainteresowałam tymi ERM. Przejrzałam ERM help i umieszczone tutaj posty (41 stron). Z prostymi skryptami już sobie radzę, ale mam kilka pytań. Np.:
1)Czy mógłby ktoś napisać (i objaśnić mi) skrypt, który będzie odpowiadał za sprawdzanie czy bohater posiada jakąś umiejętność i w zależności od tego wykonywana była by jakaś akcja? Konkretny przykład: bohater odwiedza Czarną Wieżę pojawia się tekst i mamy dwie odpowiedzi. Nie powoduje opuszczenie wieży, tak przechodzi do drugiego tekstu i ponownie mamy dwie odpowiedzi tak daje bohaterowi umiejętność Nekromancja, "nie" powoduje opuszczenie wieży, ale dodatkowo sprawdza czy bohater posiada umiejętność "Odporność na Magię" i na jakim poziomie. Jeśli nie posiada to bohater ginie po trzech dniach od zdarzenia, jeśli posiada na poziomie podstawowym, ginie cała jego armia za wyjątkiem jednej losowej jednostki, na poziomie zaawansowanym ginie np. połowa jednostek, a na eksperckim nic się nie dzieje.
2)To w ramach tego pierwszego, czy można dodać umiejętność "nekromancja" bohaterowi, który ma już zajęte wszystkie osiem slotów na umiejętności?
3)Jak usunąć bohaterowi wszystkie jednostki a zastąpić je nowymi?
4)Jak napisać skrypt, który każdego szóstego dnia tygodnia zabierałby ze skarbca 1 złoto za każdą jednostkę pierwszego poziomu, 2 złota za jednostkę drugiego poziomu itd. lub bardziej skomplikowana wersja tego skryptu, gdy nie będzie miał wystarczającej ilości złota, to odjąć mu z arami odpowiednią ilość jednostek?
5)Jak wyglądałby skrypt dla takiej sytuacji: na mapie są kopalnie, ale do uruchomienia wydobycia trzeba dostarczyć 100 chłopów, oraz czy można by zwiększyć wydobycie za większą ilość chłopów?
6)Czy da się zrobić tak, żeby kopalnie zmieniały właściciela po kilku dniach od ich przejęcia, chyba, że pozostawi się w nich jakiś garnizon np. na 3000 pkt., w celu obrony? Tak jak to jest w jednej z kampanii w HoMM V Hammers of Fate

Już ostatnie pytanie. Gdzie można dostać ten plik Pomocy ERM napisany przez Altaira bo te linki jakoś mi nie działają?

P.S. jeśli któreś skrypty są nie wykonalne, to proszę o podanie jakiejś alternatywy.

Nemomon PW
23 maja 2008, 11:27
Dawno nie pisałem w tym temacie a akurat pytasz się o coś (a przynajmniej tak mi się wydaje), o co i chciałem się spytać (co prawda winnem to zrobić w innej komnacie, ale...). Oczywiście chciałbym Ciebie również pozdrowić.

Myślę, że chodziło Ci o ten adres:

https://www.erm.acidcave.net/

A moje pytanie jest takie, czy Grota będzie miała jakiś link do tego adresu albo nawet osobny button, ponieważ póki co, widnieje on tylko na Home Page?

A co do skryptów, które podałaś, to powiem, że mi się podobają. Niemniej mam pytanie co do tej kopalni oraz Chłopków. Czyżby chodziło Ci o to, że za każde powiedzmy 100 chłopków, które dostarczysz do danej kopalni, to będzie ona dawała o jedną jednostkę zasobów więcej (1 w reszcie surowców, 2 w tartakach i kamieniołomach oraz 1000 Gold w Kopalni Złota)?

Co do dodawania umiejętności ponad 8, jest to oczywiście możliwe. Praktycznie bohater może posiadać wszystkie umiejętności. Będą one pokazywane po wciśnięciu Shift lub Ctrl oraz LPM na ikonie Doświadczenia.

Chciałbym tylko nadmienić, że wyraz "wierzę" oraz "wierzy" odnosi się do wyrazu 'wiara' i dlatego pisze się przez "erzet". Ty jednak miałaś na myśli budynek, więc powinnaś napisać przez 'samo żet" - 'wieżę' oraz 'wieży'.

Maiden PW
23 maja 2008, 13:16
Dzięki za adres. Znalazłam już poradniki i kilka skryptów. Zabieram się za lekturę i analizę.

Kopalnie, o których pytałam, miałyby działać dokładnie tak jak to zrozumiałeś tzn. za każdą kolejną setkę chłopków, kopalnia dawałaby jednostkę surowca więcej. Tak przynajmniej sobie to wyobrażam.

Jeśli już napisałeś, że możliwe jest dodanie umiejętności powyżej ośmiu, to może podasz mi jeszcze odpowiedni skrypt lub choćby coś, na czym mogłabym się wzorować pisząc własny?

I przepraszam za wtopę z wieżą. :D Już poprawiłam.

Altair PW
24 maja 2008, 02:30
Maiden:
jeśli któreś skrypty są nie wykonalne, to proszę o podanie jakiejś alternatywy.

Może ja odpowiem na twoje pytania. Skrypty o które prosisz są w zasadzie wykonalne. Trochę ich dużo, ponieważ jednak piszesz pierwszy raz w tym temacie i zadałeś precyzyjne pytanie otrzymasz wyczerpującą odpowiedź.

Po kolei:
1. Zakładam na wstępie, że czarna wieża to obiekt 63/47.

ZVSE

!?OB63/47&1000;

!!VRz111:S^Pytanie^;
!!VRz112:S^Tak^;
!!VRz113:S^Nie^;
!!VRz117:S^^;
!!IF:G1/8/16/z111/z112/z113/z117/z117/z117/z117/z117/z117/z117/z117/z117/z117;
!!FU&v8=2:E;**opuszczenie
!!VRz111:S^Pytanie^;
!!VRz112:S^Tak^;
!!VRz113:S^Nie^;

!!VRz117:S^^;
!!IF:G1/8/16/z111/z112/z113/z117/z117/z117/z117/z117/z117/z117/z117/z117/z117;
!!HE-1:S12/?y10;**sprawdzenie poziomu nekromancji
!!FU&y10>0:E;**opuszczenie
!!HE-1:S26/?y10;**sprawdzenie poziomu odporności
!!FU5508&v8=2:Py10;**kara
!!FU&v8=2:E;**opuszczenie
!!HE-1:S12/1; **dodanie nekromancji

!?FU5508;
!!VRz10:S^killfade.82M^;
!!SN&x1=0:Pz10;**dźwięk ginięcia
!!HE-1&x1=0:K;**ginie hiros
!!FU&x1=0:E;
!!VRv10:C0/0/0/0/0/0/0;
!!VRv20:S-1;
!!DO5509/0/6/1&x1=1:P;**odczyt slotow
!!VRv21&x1=1:S10 Rv20;**losowanie
!!DO5510/0/6/1&x1=1:P;**kasowanie
!!FU&x1=1:E;
!!DO5511/0/6/1&x1=2:P;**kasowanie połowy

!?FU5509;
!!VRx1:Sx16+10;
!!HE-1:C0/x16/?y1/?x2;
!!VRvx1&x2>0:Sx16+1;
!!VRv20&x2>0:+1;

!?FU5510;
!!VRx8:Svv21-1;
!!HE-1&x16<>x8:C0/x16/?y1/0;
!!HE-1&x16=x8:C0/x16/?y1/1;

!?FU5511;
!!HE-1:C0/x16/?y1/?x2;
!!VRx2::2;
!!VRx2&x2<1:S1;
!!HE-1:C0/x16/?y1/x2;

3. Usuwanie jest proste: !!HE-1:C0/nr_slotu/?y1/0;
Dodawanie jednostek można zrobić na wiele sposobów (w ERM Helpie są te sposoby) np.
!!HE-1:C0/nr_slotu/typ_jednostki/ilość;


4. Skrypt na pobieranie złota za jednostki 6 dnia jest prosty:

ZVSE

!#TM15:S6/999/7/255;
!?TM15;
!!VRv10:S0;
!!DO150/0/155/1:P;
**IF&1000:M^Koszt utrzymania armii: %V10^;
!?FU150;
!!OW:C?y1; ** check current player
!!HEx16:O?y2; ** check owner
!!DO151/0/6/1&y1=y2:Px16/y2;

!?FU151;
!!HEx1:C0/x16/?y1/?y2;
!!MA&y1>-1:Ly1/?y4;
!!VRy4:+1;
!!VRy5:Sy4*y2*-1;
!!VRv10:-y5;
!!OW&y1>-1:Rx2/6/dy5;
!!OW&y1>-1:Rx2/6/?y6;
!!OW&y1>-1/y6<1:Rx2/6/0;

I tu kilka uwag. Skrypt pobiera złoto jeśli jest w skarbcu. W przeciwnym wypadku nic nie robi. Zliczane są tylko jednostki, które posiadają bohaterowie te w miastach nie są liczne.


Maiden:
Jak wyglądałby skrypt dla takiej sytuacji: na mapie są kopalnie, ale do uruchomienia wydobycia trzeba dostarczyć 100 chłopów, oraz czy można by zwiększyć wydobycie za większą ilość chłopów?

Byłby dłuugi i wyglądałby tak:
ZVSE

!#PO12/9/0:V0/-1;

!#TM16:S1/999/1/255;

!?TM16;
!!UN:U53/-1/?y2;
!!OW:C?y1;
!!DO152/1/y2/1:Py1;

!?FU152;
!!UN&x16=1:U53/-1/1/1;
!!UN&x16>1:U53/-1/-1/1;
!!MN1:R?y2/1 O?y5;
!!PO1:V0/?y3;
!!VRy4:Sy3;
!!VRy4&y2=6:Sy3*1000;
!!VRy4&y2=0:Sy3*2;
!!VRy4&y2=2:Sy3*2;
!!OW&x1=y5:Rx1/y2/dy4;

!?FU153;
!!HEx1:C0/x16/?y1/?y2;
!!HEx1&v51<>-1/y1=139:C0/x16/?x2/0;
!!HEx1&v51<>-1/y1=139:C0/v51/?x2/dy2;
!!VRv51&v51=-1/y1=139:Sx16;

!?CM;

!!CM:I?y1 F?y2;
!!FU&y1<>37|y2<>512:E;

!!OW:C?y10;
!!OW:Ay10/?y11;
!!CM:P?y2/?y3/?y4;
!!HEy11&y11>-1:P?y7/?y8/?y9;
!!VRy20:Sy2-y7;
!!VRy20&y20<0:*-1;
!!VRy16&y20=1:S1;
!!VRy17:S0;
!!VRy21:Sy3-y8;
!!VRy21&y21<0:*-1;
!!VRy17&y21=1:S1;
!!VRy16&y15<>1:S0;
!!VRy17&y15<>1:S0;
!!VRy22:S0;
!!VRy22&y20<2/y21<2:S1;
!!FU&y22<>1:E;
!!TRy2/y3/y4:E?v10;
!!FU&v50=1:E;
!!OBy2/y3/y4:T?y40;

!!FU&y40<>53:E;
!!MNy2/y3/y4:O?y41;
!!FU&y41<>y10:E;
!!POy2/y3/y4:V0/?y42;

!!IF&y42=-1:Q2/21/139/2^Aby rozpocząć produkcje w obiekcie potrzebnych jest 100 Chłopów. Czy chcesz rozpocząć produkcje?^;
!!IF&y42>-1:Q2/21/139/2^Aby zwiększyć dzienną produkcje surowca potrzebnych jest 100 Chłopów. Czy chcesz zwiększyć produkcje?^;
!!VRv51:S-1;
!!FU&-2:E;
!!DO153/0/6/1&2:Py11;

!!HEy11&v51<>-1:C0/v51/?y20/?y30;
!!IF&y30<100|v51=-1:M^Nie masz tylu chłopów!^;
!!CM&y30<100|v51=-1:R0;
!!FU&v51=-1:E;

!!FU&y30<100:E;
**VRy42:+1;
!!POy2/y3/y4:V0/d1;
!!VRy30:-100;
!!HEy11:C0/v51/?y20/y30;
!!UN:R1;

!!CM:R0;


Teraz odpowiadam jak to działa. Standardowo wszystkie kopalnie, tartaki itd. Działają normalnie. Aby dana kopalnia nic nie produkowała i wymagała uruchomienia trzeba w skrypcie na początku dodać linijkę (linijki):

!#POx/y/p:V0/-1;

Za x, y, p podajemy współrzędne kopalni. Co się się stanie jeśli zamiast -1 podstawimy inna liczbę? Jeśli wstawimy 0 to będzie działać normalnie a wyższe liczby to poziom ulepszenia. Ulepszamy przez kliknięcie prawym przyciskiem na obiekcie (musi znajdować się przy nim nasz bohater i kopalnia musi należeć do nas)

Maiden:
Czy da się zrobić tak, żeby kopalnie zmieniały właściciela po kilku dniach od ich przejęcia, chyba, że pozostawi się w nich jakiś garnizon np. na 3000 pkt., w celu obrony? Tak jak to jest w jednej z kampanii w HoMM V Hammers of Fate

Oczywiście, że się da. 3000 pkt tu jak rozumiem chodzi ci o punkty życia wszystkich w garnizonie?

Jak widać z pozoru wydałoby się proste skrypty nie już takie proste gdy zostaną napisane. Mi zrobienie tego zajęło kilka ładnych godzin. Mam nadzieje, że przydadzą się komuś jeszcze.

Nemomon:
A moje pytanie jest takie, czy Grota będzie miała jakiś link do tego adresu albo nawet osobny button, ponieważ póki co, widnieje on tylko na Home Page?

Nie tylko. Zajrzyj do działu WoG. :P





Maiden PW
25 maja 2008, 12:28
Dzięki za szybką odpowiedź. Sprawdziłam i wszystkie skrypty działają, ale muszę jeszcze je przeanalizować, aby zadać kolejne pytania. Na chwile obecną urodziły mi się dwa.

1.Co trzeba dodać do tego skryptu z czarną wieżą, aby efekt zabierania jednostek pojawiał się po kilku dniach? Mam ochotę też poprzerabiać odrobinę twoje skrypty. Czy będę mogła wysłać Ci na maila moje wypociny do sprawdzenia, bo wpierw chciałabym sama się z nimi pomęczyć, a dopiero później prosić o pomoc? Chodzi o to aby nie zaśmiecać forum.

2.Jak z tym skryptem o przejmowaniu kopalni i umieszczaniu w nich obowiązkowego garnizonu? A te 3000 pkt. to początkowo myślałam o tych które określają wartość bojową jednostki (fight value), ale myślę, że z punktami życia będzie łatwiej.


Altair PW
25 maja 2008, 21:43
Maiden:
Czy będę mogła wysłać Ci na maila moje wypociny do sprawdzenia, bo wpierw chciałabym sama się z nimi pomęczyć, a dopiero później prosić o pomoc? Chodzi o to aby nie zaśmiecać forum.

Staram się zawsze (o ile mam czas) udzielać odpowiedzi na pytania i prośby w tym temacie. Jednak każdy kto chce szerzej ze mną podyskutować na ten temat ERM, zmodyfikować już istniejący skrypt (czy podany już przeze mnie) i poprosić o sprawdzenie poprawności kodu może wysłać mail do mnie lub też skontaktować się przez komunikator. Postaram się wtedy pomóc.

1. W wypadku czarnej wieży po prostu skróciłem skrypt aby był bardziej czytelny. Aby działał efekt znikania jednostek po kilku dniach, należy użyć Przełącznika czasowego TM wywoływanego codziennie. Następnie użyć zmiennej w i stworzenie pętli dla wszystkich bohaterów.

2.Co do kopalni i umieszczania w niej obowiązkowego garnizonu:

ZVSE
!#TM14:S1/999/1/255;

!?TM14;
!!UN:U53/-1/?y2;
!!OW:C?y1;
!!DO155/1/y2/1:Py1;

!?FU155;
!!UN&x16=1:U53/-1/1/1;
!!UN&x16>1:U53/-1/-1/1;
!!VRv4:C0/0;
!!MN1:O?y5;
!!DO156/0/6/1&y5=x1:P;

!!PO1&y5=x1/v5<3000:V1/?x6;
**IF:M^%Y5 %V5^;
!!VRx6&y5=x1/v5<3000:+1;
!!PO1&y5=x1/v5<3000:V1/x6;
!!MN1&y5=x1/v5<3000/x6>2:O-1;
!!PO1&y5=x1/v5<3000/x6>2:V1/0;
!?FU156;
!!MN1:Mx16/?x1/?x2;
!!MA&x1>-1:Px1/?x3;
!!VRx4&x1>-1:Sx3*x2;
!!VRv5&x1>-1:+x4;

Skrypt sprawdza czy wszystkie jednostki mają łącznie 3000 pkt. życia. Aby użyć fight value wystarczy zamienić MA:P na MA:F.

Maiden PW
29 maja 2008, 12:11
Dzięki za wszystkie skrypty. Teraz sobie nad nimi pracuję. Mam jednak jeszcze jedno (nie ostatnie) pytanie. Aby wstawić obrazek "zewnętrzny" używam komendy IF:D bla bla...
Wszystko działa tylko tekst, który mogę umieścić nad obrazkiem (ten wyświetlany na biało) jest bardzo krótki i dłuższe zdania nie są wyświetlane w całości. Czy wie ktoś w jaki inny sposób można wstawić .jpg oraz tekst przyzwoitej długości?

Altair PW
30 maja 2008, 00:32
Co do tego tekstu nad obrazkiem to trzeba po prostu używać znaków nowej linii (enter). Niestety nie są one dodawane automatycznie. Tekst nie rozdzielony nimi jest wyświetlany w jednej linii.

Kulex PW
1 czerwca 2008, 09:32
Znalazłem skrypt, który zmienia ściany lochu na lodowe, jeśli jest przy nich śnieg.
https://forum.df2.ru/index.php?showtopic=5807&st=280
Chyba działa tylko pod WOGiem TE.

Altair PW
1 czerwca 2008, 13:40
Powinno działać i pod zwykłym Wogiem trzeba tylko najpierw zainstalować patch z tą grafiką. :)

Kulex PW
2 czerwca 2008, 10:39
Patch z tą grafiką?
Wskaż linię, tam gdzie jest nazwa DEFa, bo jej nie widzę.
Chyba korzystają z podmiany palety kolorów.

avatar PW
2 czerwca 2008, 11:55
A widziałeś w ogóle jakiś skrypt, w którym była linia do DEFa?

Kulex PW
2 czerwca 2008, 13:34
A ten ze stworami?

Altair PW
2 czerwca 2008, 15:25
Wystarczy przeczytać w poście z obrazkiem. Trzeba to pobrać i zainstalować.
https://slil.ru/25822895

https://slil.ru/25822891

avatar PW
2 czerwca 2008, 15:38
Nie wiem jak mozna to prościej wytłumaczyć: jeśli chce się mieć nową grafikę w grze, to trzeba ją doinstalować... Przecież ta cała dyskusja w necie o nowych jednostkach - chcesz mieć nowa jednostkę - stwórz jej animację a później DOŁÓŻ/PODMIEŃ ją do istniejących grafik w grze. Sądzisz, że z samych linijek kodu stworzy się nowa grafikę?

Dragonar PW
4 czerwca 2008, 22:56
Mam jakiś dziwny błąd ERM. Gdy mam zamek Wrota Żywiołów i wpiszę kod na wszystkie budowle (wogminastirith) i kliknę na fort, kapitol lub znak V (wyjście z miasta) to pokazuje się:

coś tam z 4 linijki.
pyta się o coś po angielsku trzeba kliknąć V bo jak nie to klikasz w nieskończoność.

potem komenda ERM ma złą składnię, zostanie pominięta.

potem coś tam 5 linijek.

i znowu to samo od nowa...

trzeba klikać aż się wyłączy (nawet 100 razy).

Dokładny opis:

-----------------------
ERM syntax Error.
File: erm
Line: 6645
Reason:
"HE$"-cannot find hero (out of range).

Save all ERM vars to WOGERMLOG.TXT (may take time)?
-----------------------
-----Context-----
A1/?y-26/0;.....
-----------------

AltairAltairWycięto nieistotny fragment komunikatu


Niestety nie mogę wysyłać maila, więc długie to trochę... proszę o pomoc!!!
Bardzo przepraszam, że to takie długie i bardzo proszę o pomoc.

Altair PW
5 czerwca 2008, 02:46
Raczej trudno będzie ci pomóc, ponieważ potrzebuje zapisu stanu gry z tej mapy. Błąd wystąpił w którymś skrypcie (zakładam, że tylko skrypty Wogifikacji były tam użyte). Wynika z tego, że jakaś składnia odwołuje się numeru hirosa który nie istnieje. Jedyny sposób na naprawę tego to poprawienie odpowiedniego skryptu.


Dragonar PW
6 czerwca 2008, 20:04
Dziękuję Altairze! Wszystko działa idealnie! W zamian mogę ci przysłać łatki na wygląd jednostek. Pobrałem pakiet wyglądów jednostek (Piekielny Baron, Święty Feniks, Piekielna Hydra), Jeśli komuś podobała się Hydra, a nie podobał Baron to podzieliłem łatkę na poszczególne jednostki(3). Mogę przysłać mailem jeśli chcesz...mógłbyś je zamieścić osobno...
Z tym dzikiem to już nie...widziałem go na forum...

Altair PW
7 czerwca 2008, 10:46
Oczywiście napiszę taki skrypt jeśli tylko mi podasz gdzie w WoGu (tudzież NU) jest SAM dzik. Bo nijak nie mogę znaleźć go żadnej w dokumentacji. ;)
strona: 1 - 2 - 3 ... 40 - 41 - 42 ... 81 - 82 - 83
temat: [WoG, ERA] Skrypty ERM

powered by phpQui
beware of the two-headed weasel